Calcul d’âge ou différence entre deux dates dans Excel

Vous pouvez avoir besoin de connaître l’écart entre deux dates dans Excel dans différents cas; par exemple pour calculer l’âge entre deux dates, ou encore combien reste exactement en terme de mois et jours avant qu’un produit n’expire, etc.

Pour cela, utilisez la fonction DATEDIF comme je vous montre ci-dessous.

A- Syntaxe de la fonction DATEDIF

La syntaxe de la fonction DATEDIF d’Excel est comme suit:

=DATEDIF(Date_de_début; Date_de_fin; Unité)

Dans la formule, l‘argument Unité peut être une des valeurs suivantes: “Y”, “M”, “D”, “YM”, “MD”, ou “YD”.

Plus d’explications dans les exemples des sections ci-dessous, où je vais calculer la différence entre deux dates en années, puis en mois, puis en jours, puis en semaines; et enfin, je vais calculer cette différence à la fois en années, mois et jours.

B- Calcul d’âge en années seulement

La formule à utiliser pour calculer l’âge en années, est comme suit:

=DATEDIF(Date_de_naissance; Date_du_jour; "Y") 

Comme dernier argument de la fonction, je mets “Y” pour calculer la différence entre deux dates en années (Y pour “Year” en Anglais).

Exemple pratique: Dans cet exemple, je vais calculer l’âge du personnel d’une entreprise ou administration, pour par exemple savoir le nombre d’années restant à chacun avant la retraite:

Je vais d’abord utiliser la fonction AUJOURDHUI pour obtenir la date du jour dans la cellule C2.

Puis, je calcule l’âge dans la cellule D2 en y saisissant la formule:

=DATEDIF(B2; C2; "Y") 

Le résultat de la différence entre les deux dates 07/04/1965 et 06/01/2020 est 54 ans.

En réalité, c’est un tout petit peu plus, mais je suis en train de calculer la différence entre deux dates en années avec la fonction DATEDIF qui ne renvoie qu’un nombre entier comme résultat.

C- Calcul d’âge en mois seulement

La formule à utiliser pour calculer l’âge en mois, est comme suit:

=DATEDIF(Date_de_naissance; Date_du_jour; "M") 

Comme dernier argument de la fonction, je mets “M” pour calculer la différence entre deux dates en mois (M correspond au mot “mois”, mais à l’origine, c’est plutôt pour “Month” en Anglais).

Dans le même exemple utilisé ci-avant, je calcule l’âge dans la cellule E2 en y saisissant la formule suivante:

=DATEDIF(B2; C2; "M") 

Dans mon exemple illustré ci-dessus, le résultat de la différence entre les deux dates 07/04/1965 et 06/01/2020 est 656 mois.

D- Calcul d’âge en jours seulement

La formule à utiliser pour calculer l’âge en jours, est comme suit:

=DATEDIF(Date_de_naissance; Date_du_jour; "D") 

Comme dernier argument de la fonction, je mets “D” pour calculer la différence entre deux dates en jours (D pour “Day” en Anglais).

Toujours, en utilisant le même exemple, je calcule l’âge en jours dans la cellule F2 en y saisissant la formule suivante:

=DATEDIF(B2; C2; "D") 

Dans mon exemple illustré ci-dessus, le résultat de la différence entre les deux dates 07/04/1965 et 06/01/2020 est 19997 jours.

Remarque: Vous pouvez aussi calculer la différence en jours entre deux dates en Excel, en leur appliquant une simple soustraction.

Pour le présent exemple, je pouvais juste saisir dans la cellule F2 la formule suivante:

=C2-B2

E- Calcul d’âge en semaines seulement

Vous pouvez calculer la différence entre deux dates en semaines en utilisant la même formule que pour les jours, mais en divisant par 7.

La syntaxe sera donc:

=DATEDIF(Date_de_naissance; Date_du_jour; "D")/7

Et la formule dans mon exemple deviendra donc:

=DATEDIF(B2; C2; "D")/7

avec B2 la cellule contenant la date de début et C2 la cellule contenant la date de fin (date d’aujourdhui ou autre).

F- Calcul d’âge en années, mois et jours

C’est, je présume, le cas le plus fréquent et le plus utile.

La formule à utiliser pour calculer l’âge en détail (c’est à dire, à la fois en années, mois, et jours), est comme suit:

=DATEDIF(Date_de_naissance; Date_du_jour; "y") & " ans, " 
& DATEDIF(Date_de_naissance; Date_du_jour; "ym") & " mois et " 
& DATEDIF(Date_de_naissance; Date_du_jour; "md") & " jours" 

Dans la formule, vous aurez besoin de combiner trois formules par l’opérateur & et d’utiliser “Y”, “YM” et “MD” comme arguments:

– “Y”: pour calculer la différence entre deux dates en années (Y pour “Year” en Anglais).
– “YM”: pour calculer la différence entre deux dates juste en mois, sans prendre en compte les années.
– “MD”: pour calculer la différence entre deux dates juste en jours, sans compter les années ou les mois.

N.B: Vous pouvez utiliser la combinaison de touches Alt + Entrée pour insérer un saut de ligne dans la formule, pour plus de lisibilité.

La deuxième date peut être la date du jour comme dans notre cas, ou bien une date définie quelconque.

Les parties “ans”, “mois et”, et “jours”, quant à elles, sont du texte pour mieux clarifier le résultat, sinon on aurait eu comme résultat juste une séquence de chiffres, sans aucune signification.

Appliquant tout cela à mon exemple utilisé tout au long de ce tutoriel, je me retrouve avec la formule suivante que j’ai placé dans la cellule G2:

=DATEDIF(B2; C2; "y") & " ans, " 
& DATEDIF(B2; C2; "ym") & " mois et " 
& DATEDIF(B2; C2; "md") & " jours" 

Le résultat de mon exemple est maintenant bien plus clair et précis:

La différence entre les deux dates 07/04/1965 et 06/01/2020 est: 54 ans, 8 mois et 30 jours.

G- Mises en garde relatives au calcul de différences entre dates

1- Prérequis de l’utilisation de la fonction DATEDIF

Pour que la fonction DATEDIF fonctionne correctement:

– Les deux dates doivent être postérieures ou égales à la date du 01/01/1900,
– Et la date de début doit être antérieure à la date de fin. Si la date de début est supérieure à la date de fin, Excel vous affichera l’erreur #NOMBRE! Il suffirait donc de permuter les deux dates dans la formule pour obtenir le bon résultat ou bien de corriger la date erronée le cas échéant.

2- Faciliter la lecture des formules longues

Pour faciliter la lecture de votre formule si elle est longue, utilisez la combinaison des touches Alt + Entrée pour insérer un saut de ligne dans la formule au niveau de l’emplacement précis que vous voulez.

Aussi, cliquez sur la flèche tout à droite de la barre de formule pour étendre verticalement son espace d’affichage.

3- Ecart de dates vs Durée globale

La fonction DATEDIF calcule la différence entre deux dates dans Excel, c’est à dire l’écart entre deux dates et non la durée globale; autrement dit, le résultat n’inclut qu’une seule date et non les deux en même temps.

Exemple:

– Pour les deux dates 01/01/2020 et 31/01/2020: la fonction DATEDIF donne comme résultat 0 mois (en cas de calcul par mois), ou 30 jours (en cas de calcul par jours).
– Pour les deux dates 01/01/2020 et 01/02/2020: la fonction DATEDIF donne dans ce cas le résultat 1 mois (en cas de calcul par mois), ou 31 jours (en cas de calcul par jours).

---

Voilà; j’espère que ce tutoriel vous ait été utile. J’ai essayé d’être le plus clair possible; mais si jamais vous éprouvez une quelconque difficulté, n’hésitez pas à la noter dans les commentaires.